scn aaDRSporenDummySkript

;Geschrieben von Bethesda Softworks
;kleinere nderungen durch DarkRuler2500
;===========================================

short triggered
short stage
float timer
ref mySelf

;#########################################
;# Aktivierung der Falle durch Anklicken #
;#########################################
begin onActivate
if triggered == 0
	set triggered to 1
	set stage to 1
	playgroup forward 1
	set timer to 17
endif
end

;############################################
;# Aktivierung der Falle durch Drberlaufen #
;############################################
begin onTriggerActor Player					;lsche das "Player", um jeden Actor zum Auslser zu machen!
if triggered == 0 && timer <= 0
	set mySelf to getSelf
	activate mySelf 1
endif
end

;#############################################
;# Aktivierung der Falle durch Pfeilbeschuss #
;#############################################
begin onHitWith
if triggered == 0 && timer <= 0
	set mySelf to getSelf
	activate mySelf 1
endif
end

;##############################################
;# Aktivierung der Falle durch Zauberbeschuss #
;##############################################
begin onMagicEffectHit
if triggered == 0 && timer <= 0
	set mySelf to getSelf
	activate mySelf 1
endif
end

;##################################
;# Weiterfhrung nach Aktivierung #
;##################################
begin gameMode
	if timer > 0
		set timer to timer - getSecondsPassed
	endif
	if stage == 1 && timer <= 16.75
		set stage to 2
		;Cast ZauberID MySelf		;Hier fr ZauberID die ID des Zaubers einsetzen, dessen Wirkung die Sporenwolke haben soll.
	endif
	if triggered == 1 && timer <= 0
		set triggered to 0
	endif
end

;###########################################
;# Nach der Respawnzeit alles zurcksetzen #
;###########################################
begin onReset

	Reset3DState
	set triggered to 0
	set stage to 0

end
